-
-
Notifications
You must be signed in to change notification settings - Fork 42
Expand file tree
/
Copy pathWriteCsv.cfc
More file actions
216 lines (189 loc) · 7.81 KB
/
Copy pathWriteCsv.cfc
File metadata and controls
216 lines (189 loc) · 7.81 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
component extends="BaseCsv" accessors="true"{
property name="data" setter="false";
property name="parallelThreadsToUse" type="numeric" default=0 setter="false";
property name="useQueryColumnsAsHeader" type="boolean" default="false" setter="false";
property name="useStructKeysAsHeader" type="boolean" default="false" setter="false";
public WriteCsv function init( required spreadsheetLibrary ){
super.init( spreadsheetLibrary=arguments.spreadsheetLibrary, initialPredefinedFormat="EXCEL" );
return this;
}
/* Public builder API */
public WriteCsv function fromData( required any data ){
if( !IsArray( arguments.data ) && !IsQuery( arguments.data ) )
Throw( type=variables.library.getExceptionType() & ".invalidDataForCsv", message="Invalid data", detail="Please pass your data as a query, an array of arrays, or an array of structs" );
variables.data = arguments.data;
return this;
}
public WriteCsv function toFile( required string path ){
if( arguments.path.Left( 4 ) == "ram:" )
Throw( type=variables.library.getExceptionType() & ".vfsNotSupported", message="Invalid file path", detail="Virtual File System (RAM) paths are not supported for writing to CSV. Try just returning the CSV string and then using FileWrite() to write to the VFS path" );
variables.filepath = arguments.path;
return this;
}
public WriteCsv function withParallelThreads( numeric numberOfThreads=2 ){
/* WARNING: can have unexpected results such as rows out of order or system crashes. USE WITH CARE. */
if( arguments.numberOfThreads < 2 ){
variables.parallelThreadsToUse = 0;
return this;
}
variables.parallelThreadsToUse = Int( arguments.numberOfThreads );
return this;
}
public WriteCsv function withQueryColumnsAsHeader( boolean state=true ){
variables.useQueryColumnsAsHeader = arguments.state;
return this;
}
public WriteCsv function withStructKeysAsHeader( boolean state=true ){
variables.useStructKeysAsHeader = arguments.state;
return this;
}
// final execution
public any function execute(){
if( IsNull( variables.data ) )
Throw( type=variables.library.getExceptionType() & ".missingDataForCsv", message="Missing data", detail="Please specify the data you want to write using '.fromData( data )'" );
var appendable = newAppendableBuffer();
printTo( appendable );
if( IsNull( variables.filepath ) ) {
if( getLibrary().getIsBoxlang() ) // Boxlang somehow modified the .toString() call, this will ensure we aren't trimming whitespace
return appendable.substring( JavaCast( "int", 0 ), JavaCast( "int", appendable.length() ) );
return appendable.toString();
}
return this;
}
/* Private */
private void function printTo( required appendable ){
try{
if( IsQuery( data ) ){
setQueryColumnsAsHeaderIfRequired();
var printer = newPrinter( arguments.appendable );
printFromQuery( printer );
return;
}
setStructKeysAsHeaderIfRequired();
var printer = newPrinter( arguments.appendable );
printFromArray( printer );
}
finally{
// Boxlang needs another explicit row call to have a trailing new row at the end of a file
if(
getLibrary().getIsBoxlang()
&& !IsNull( variables.filepath )
&& local.KeyExists( "printer" )
)
printRowFromArray( [], printer );
if( local.KeyExists( "printer" ) )
printer.close( JavaCast( "boolean", true ) );
}
}
private void function setQueryColumnsAsHeaderIfRequired(){
if( !variables.useQueryColumnsAsHeader )
return;
var columns = variables.library.getQueryHelper()._QueryColumnArray( variables.data );
super.withHeader( columns );
}
private void function setStructKeysAsHeaderIfRequired(){
if( !variables.useStructKeysAsHeader || !variables.data.Len() || !IsStruct( variables.data[ 1 ] ) )
return;
var keys = variables.data[ 1 ].KeyArray();
super.withHeader( keys );
}
private any function newPrinter( required appendable ){
return variables.library.createJavaObject( "org.apache.commons.csv.CSVPrinter" ).init( arguments.appendable, variables.format );
}
private any function newAppendableBuffer(){
if( IsNull( variables.filepath ) )
return variables.library.getStringHelper().newJavaStringBuilder();
return newBufferedFileWriter();
}
private any function newBufferedFileWriter(){
var charset = CreateObject( "java", "java.nio.charset.Charset" ).forName( "UTF-8" );
if( variables.library.getIsBoxlang() ){
//boxlang (or java21?) doesn't recognize ACF/Lucee signatures
var path = CreateObject( "java", "java.nio.file.Paths" ).get( JavaCast( "string", variables.filepath ) );
return CreateObject( "java", "java.nio.file.Files" ).newBufferedWriter( path, charset );
}
var path = CreateObject( "java", "java.nio.file.Paths" ).get( JavaCast( "string", variables.filepath ), [] );
return CreateObject( "java", "java.nio.file.Files" ).newBufferedWriter( path, charset, [] );
}
private void function printFromArray( required printer ){
var printRowFunction = function( row ){
printRowFromArray( row, printer );//don't scope
};
if( useParallelThreads() ){
printUsingParallelThreads( printRowFunction );
return;
}
variables.data.Each( printRowFunction );
}
private void function printFromQuery( required printer ){
var columns = variables.library.getQueryHelper()._QueryColumnArray( variables.data );
var printRowFunction = function( row ){
printRowFromQuery( row, columns, printer );//don't scope
};
if( useParallelThreads() ){
printUsingParallelThreads( printRowFunction );
return;
}
variables.data.Each( printRowFunction );
}
private void function printUsingParallelThreads( required function printRowFunction ){
variables.data.Each(
arguments.printRowFunction
,true
,variables.parallelThreadsToUse
);
}
private function printRowFromArray( required row, required printer ){
if( IsStruct( arguments.row ) )
arguments.row = _StructValueArray( arguments.row );
arguments.row = checkArrayRow( arguments.row );
printRow( arguments.printer, arguments.row );
}
private function printRowFromQuery( required row, required columns, required printer ){
arguments.row = convertQueryRowToArray( arguments.row, arguments.columns );
printRow( arguments.printer, arguments.row );
}
private void function printRow( required printer, required array row ){
arguments.printer.printRecord( JavaCast( "string[]", row ) );//force numbers to strings to avoid 0.0 formatting
}
private array function checkArrayRow( required array row ){
var totalColumns = arguments.row.Len();
cfloop( from=1, to=totalColumns, index="local.i" ){
var value = arguments.row[ i ];
if( !IsSimpleValue( value ) )
Throw( type=variables.library.getExceptionType() & ".invalidDataForCsv", message="Invalid data", detail="Your data contains complex values which cannot be output to CSV" );
arguments.row[ i ] = formatDateString( value );
}
return arguments.row;
}
private string function formatDateString( required any value ){
if( !variables.library.getDateHelper().isDateObject( arguments.value ) )
return arguments.value;
return DateTimeFormat( arguments.value, variables.library.getDateFormats().DATETIME );
}
private array function convertQueryRowToArray( required struct row, required array columns ){
var result = [];
for( var column IN arguments.columns ){
var cellValue = formatDateString( arguments.row[ column ] );
result.Append( cellValue );
};
return result;
}
private boolean function useParallelThreads(){
return ( variables.parallelThreadsToUse > 1 );
}
private array function _StructValueArray( required struct data ){
try{
return StructValueArray( arguments.data ); // Lucee 5.3.8.117+, ACF 2025
}
catch( any exception ){
if( !exception.message.REFindNoCase( "undefined|no matching function" ) )
rethrow;
var result = [];
for( var key in arguments.data ){
result.Append( arguments.data[ key ] );
}
return result;
}
}
}